Man1 - zshzle.1

zshzle - zsh command line editor

If the ZLE option is set (which it is by default in interactive shells) and the shell input is attached to the terminal, the user is able to edit command lines.

There are two display modes. The first, multiline mode, is the default. It only works if the TERM parameter is set to a valid terminal type that can move the cursor up. The second, single line mode, is used if TERM is invalid or incapable of moving the cursor up, or if the SINGLE_LINE_ZLE option is set. This mode is similar to ksh, and uses no termcap sequences. If TERM is “emacs”, the ZLE option will be unset by default.

The parameters BAUD, COLUMNS, and LINES are also used by the line editor. See Parameters Used By The Shell in /zshparam/(1).

The parameter zle_highlight is also used by the line editor; see Character Highlighting below. Highlighting of special characters and the region between the cursor and the mark (as set with set-mark-command in Emacs mode, or by visual-mode in Vi mode) is enabled by default; consult this reference for more information. Irascible conservatives will wish to know that all highlighting may be disabled by the following setting:

    zle_highlight=(none)

In many places, references are made to the numeric argument. This can by default be entered in emacs mode by holding the alt key and typing a number, or pressing escape before each digit, and in vi command mode by typing the number before entering a command. Generally the numeric argument causes the next command entered to be repeated the specified number of times, unless otherwise noted below; this is implemented by the digit-argument widget. See also the Arguments subsection of the Widgets section for some other ways the numeric argument can be modified.

A keymap in ZLE contains a set of bindings between key sequences and ZLE commands. The empty key sequence cannot be bound.

There can be any number of keymaps at any time, and each keymap has one or more names. If all of a keymap’s names are deleted, it disappears. bindkey can be used to manipulate keymap names.

Initially, there are eight keymaps:

emacs

EMACS emulation

viins

vi emulation - insert mode

vicmd

vi emulation - command mode

viopp

vi emulation - operator pending

visual

vi emulation - selection active

isearch

incremental search mode

command

read a command name

.safe

fallback keymap

The `*.safe*’ keymap is special. It can never be altered, and the name can never be removed. However, it can be linked to other names, which can be removed. In the future other special keymaps may be added; users should avoid using names beginning with `*.*’ for their own keymaps.

In addition to these names, either `*emacs*’ or `*viins*’ is also linked to the name `*main*’. If one of the VISUAL or EDITOR environment variables contain the string `*vi*’ when the shell starts up then it will be `*viins*’, otherwise it will be `*emacs*’. bindkey’s -e and -v options provide a convenient way to override this default choice.

When the editor starts up, it will select the `*main*’ keymap. If that keymap doesn’t exist, it will use `*.safe*’ instead.

In the `*.safe*’ keymap, each single key is bound to self-insert, except for ^J (line feed) and ^M (return) which are bound to accept-line. This is deliberately not pleasant to use; if you are using it, it means you deleted the main keymap, and you should put it back.

The ZLE module contains three related builtin commands. The bindkey command manipulates keymaps and key bindings; the vared command invokes ZLE on the value of a shell parameter; and the zle command manipulates editing widgets and allows command line access to ZLE commands from within shell functions.

bindkey [ options ] -l [ -L ] [ keymap … ]

bindkey [ options ] -d

bindkey [ options ] -D keymap …

bindkey [ options ] -A old-keymap new-keymap

bindkey [ options ] -N new-keymap [ old-keymap ]

bindkey [ options ] -m

bindkey [ options ] -r in-string …

bindkey [ options ] -s in-string out-string …

bindkey [ options ] in-string command …

bindkey [ options ] [ in-string ] bindkey’s options can be divided into three categories: keymap selection for the current command, operation selection, and others. The keymap selection options are:

-e Selects keymap `*emacs*’ for any operations by the current command, and also links `*emacs*’ to `*main*’ so that it is selected by default the next time the editor starts.

-v

Selects keymap `*viins*’ for any operations by the current command, and also links `*viins*’ to `*main*’ so that it is selected by default the next time the editor starts.

-a

Selects keymap `*vicmd*’ for any operations by the current command.

-M keymap

The keymap specifies a keymap name that is selected for any operations by the current command.

If a keymap selection is required and none of the options above are used, the `*main*’ keymap is used. Some operations do not permit a keymap to be selected, namely:

-l List all existing keymap names; if any arguments are given, list just those keymaps.

#+begin_quote If the -L option is also used, list in the form of bindkey commands to create or link the keymaps. `*bindkey -lL* main’ shows which keymap is linked to `*main*’, if any, and hence if the standard emacs or vi emulation is in effect. This option does not show the .safe keymap because it cannot be created in that fashion; however, neither is `*bindkey -lL .safe*’ reported as an error, it simply outputs nothing.

-d

Delete all existing keymaps and reset to the default state.

-D keymap …

Delete the named /keymap/s.

-A old-keymap new-keymap

Make the new-keymap name an alias for old-keymap, so that both names refer to the same keymap. The names have equal standing; if either is deleted, the other remains. If there is already a keymap with the new-keymap name, it is deleted.

-N new-keymap [ old-keymap ]

Create a new keymap, named new-keymap. If a keymap already has that name, it is deleted. If an old-keymap name is given, the new keymap is initialized to be a duplicate of it, otherwise the new keymap will be empty.

To use a newly created keymap, it should be linked to main. Hence the sequence of commands to create and use a new keymap `*mymap*’ initialized from the emacs keymap (which remains unchanged) is:

      bindkey -N mymap emacs
      bindkey -A mymap main

Note that while `*bindkey -A* newmap main’ will work when newmap is emacs or viins, it will not work for vicmd, as switching from vi insert to command mode becomes impossible.

The following operations act on the `*main*’ keymap if no keymap selection option was given:

-m Add the built-in set of meta-key bindings to the selected keymap. Only keys that are unbound or bound to self-insert are affected.

-r in-string …

Unbind the specified /in-string/s in the selected keymap. This is exactly equivalent to binding the strings to undefined-key.

When -R is also used, interpret the /in-string/s as ranges.

When -p is also used, the in-string/s specify prefixes. Any binding that has the given /in-string as a prefix, not including the binding for the in-string itself, if any, will be removed. For example,

        bindkey -rpM viins '^['

will remove all bindings in the vi-insert keymap beginning with an escape character (probably cursor keys), but leave the binding for the escape character itself (probably vi-cmd-mode). This is incompatible with the option -R.

-s in-string out-string …

Bind each in-string to each out-string. When in-string is typed, out-string will be pushed back and treated as input to the line editor. When -R is also used, interpret the /in-string/s as ranges.

Note that both in-string and out-string are subject to the same form of interpretation, as described below.

in-string command …

Bind each in-string to each command. When -R is used, interpret the /in-string/s as ranges.

[ in-string ]

List key bindings. If an in-string is specified, the binding of that string in the selected keymap is displayed. Otherwise, all key bindings in the selected keymap are displayed. (As a special case, if the -e or -v option is used alone, the keymap is not displayed - the implicit linking of keymaps is the only thing that happens.)

When the option -p is used, the in-string must be present. The listing shows all bindings which have the given key sequence as a prefix, not including any bindings for the key sequence itself.

When the -L option is used, the list is in the form of bindkey commands to create the key bindings.

When the -R option is used as noted above, a valid range consists of two characters, with an optional `*-*’ between them. All characters between the two specified, inclusive, are bound as specified.

For either in-string or out-string, the following escape sequences are recognised:

\a

bell character

\b

backspace

\e, \E

escape

\f

form feed

\n

linefeed (newline)

\r

carriage return

\t

horizontal tab

\v

vertical tab

*\*/NNN/

character code in octal

*\x*/NN/

character code in hexadecimal

*\u*/NNNN/

unicode character code in hexadecimal

*\U*/NNNNNNNN/

unicode character code in hexadecimal

\M[*-*]/X/

character with meta bit set

\C[*-*]/X/

control character

*^*/X/

control character

In all other cases, `*\*’ escapes the following character. Delete is written as `*^?*’. Note that `*\M^?*’ and `*^\M?*’ are not the same, and that (unlike emacs), the bindings `*\M-X’ and `\e*/X/’ are entirely distinct, although they are initialized to the same bindings by `*bindkey -m*’. #+end_quote

vared *[ *-Aacghe ] [ -p prompt ] [ -r rprompt ]

into the edit buffer, and the line editor is invoked. When the editor exits, name is set to the string value returned by the editor. When the -c flag is given, the parameter is created if it doesn’t already exist. The -a flag may be given with -c to create an array parameter, or the -A flag to create an associative array. If the type of an existing parameter does not match the type to be created, the parameter is unset and recreated. The -g flag may be given to suppress warnings from the WARN_CREATE_GLOBAL and WARN_NESTED_VAR options.

If an array or array slice is being edited, separator characters as defined in $IFS will be shown quoted with a backslash, as will backslashes themselves. Conversely, when the edited text is split into an array, a backslash quotes an immediately following separator character or backslash; no other special handling of backslashes, or any handling of quotes, is performed.

Individual elements of existing array or associative array parameters may be edited by using subscript syntax on name. New elements are created automatically, even without -c.

If the -p flag is given, the following string will be taken as the prompt to display at the left. If the -r flag is given, the following string gives the prompt to display at the right. If the -h flag is specified, the history can be accessed from ZLE. If the -e flag is given, typing ^D (Control-D) on an empty line causes vared to exit immediately with a non-zero return value.

The -M option gives a keymap to link to the main keymap during editing, and the -m option gives a keymap to link to the vicmd keymap during editing. For vi-style editing, this allows a pair of keymaps to override viins and vicmd. For emacs-style editing, only -M is normally needed but the -m option may still be used. On exit, the previous keymaps will be restored.

Vared calls the usual `*zle-line-init*’ and `*zle-line-finish*’ hooks before and after it takes control. Using the -i and -f options, it is possible to replace these with other custom widgets.

If `*-t* tty’ is given, tty is the name of a terminal device to be used instead of the default /dev/tty. If tty does not refer to a terminal an error is reported.

zle

zle -l [ -L | -a ] [ string … ]

zle -D widget …

zle -A old-widget new-widget

zle -N widget [ function ]

zle -f flag [ flag… ]

zle -C widget completion-widget function

zle -R [ -c ] [ display-string ] [ string … ]

zle -M string

zle -U string

zle -K keymap

zle -F [ -L | -w ] [ fd [ handler ] ]

zle -I

zle -T [ tc function | -r tc | -L ]

zle widget [ -n num ] [ -Nw ] [ -K keymap ] args … The zle builtin performs a number of different actions concerning ZLE.

With no options and no arguments, only the return status will be set. It is zero if ZLE is currently active and widgets could be invoked using this builtin command and non-zero otherwise. Note that even if non-zero status is returned, zle may still be active as part of the completion system; this does not allow direct calls to ZLE widgets.

Otherwise, which operation it performs depends on its options:

-l [ -L | -a ] [ string ] List all existing user-defined widgets. If the -L option is used, list in the form of zle commands to create the widgets.

#+begin_quote When combined with the -a option, all widget names are listed, including the builtin ones. In this case the -L option is ignored.

If at least one string is given, and -a is present or -L is not used, nothing will be printed. The return status will be zero if all string/s are names of existing widgets and non-zero if at least one /string is not a name of a defined widget. If -a is also present, all widget names are used for the comparison including builtin widgets, else only user-defined widgets are used.

If at least one string is present and the -L option is used, user-defined widgets matching any string are listed in the form of zle commands to create the widgets.

-D widget …

Delete the named /widget/s.

-A old-widget new-widget

Make the new-widget name an alias for old-widget, so that both names refer to the same widget. The names have equal standing; if either is deleted, the other remains. If there is already a widget with the new-widget name, it is deleted.

-N widget [ function ]

Create a user-defined widget. If there is already a widget with the specified name, it is overwritten. When the new widget is invoked from within the editor, the specified shell function is called. If no function name is specified, it defaults to the same name as the widget. For further information, see the section `Widgets’ below.

-f flag [ flag… ]

Set various flags on the running widget. Possible values for flag are:

yank for indicating that the widget has yanked text into the buffer. If the widget is wrapping an existing internal widget, no further action is necessary, but if it has inserted the text manually, then it should also take care to set YANK_START and YANK_END correctly. yankbefore does the same but is used when the yanked text appears after the cursor.

kill for indicating that text has been killed into the cutbuffer. When repeatedly invoking a kill widget, text is appended to the cutbuffer instead of replacing it, but when wrapping such widgets, it is necessary to call `*zle -f kill*’ to retain this effect.

vichange for indicating that the widget represents a vi change that can be repeated as a whole with `*vi-repeat-change*’. The flag should be set early in the function before inspecting the value of NUMERIC or invoking other widgets. This has no effect for a widget invoked from insert mode. If insert mode is active when the widget finishes, the change extends until next returning to command mode.

-C widget completion-widget function

Create a user-defined completion widget named widget. The completion widget will behave like the built-in completion-widget whose name is given as completion-widget. To generate the completions, the shell function function will be called. For further information, see /zshcompwid/(1).

-R [ -c ] [ display-string ] [ string … ]

Redisplay the command line; this is to be called from within a user-defined widget to allow changes to become visible. If a display-string is given and not empty, this is shown in the status line (immediately below the line being edited).

If the optional /string/s are given they are listed below the prompt in the same way as completion lists are printed. If no /string/s are given but the -c option is used such a list is cleared.

Note that this option is only useful for widgets that do not exit immediately after using it because the strings displayed will be erased immediately after return from the widget.

This command can safely be called outside user defined widgets; if zle is active, the display will be refreshed, while if zle is not active, the command has no effect. In this case there will usually be no other arguments.

The status is zero if zle was active, else one.

-M string

As with the -R option, the string will be displayed below the command line; unlike the -R option, the string will not be put into the status line but will instead be printed normally below the prompt. This means that the string will still be displayed after the widget returns (until it is overwritten by subsequent commands).

-U string

This pushes the characters in the string onto the input stack of ZLE. After the widget currently executed finishes ZLE will behave as if the characters in the string were typed by the user.

As ZLE uses a stack, if this option is used repeatedly the last string pushed onto the stack will be processed first. However, the characters in each string will be processed in the order in which they appear in the string.

-K keymap

Selects the keymap named keymap. An error message will be displayed if there is no such keymap.

This keymap selection affects the interpretation of following keystrokes within this invocation of ZLE. Any following invocation (e.g., the next command line) will start as usual with the `*main*’ keymap selected.

-F [ -L | -w ] [ fd [ handler ] ]

Only available if your system supports one of the `poll’ or `select’ system calls; most modern systems do.

Installs handler (the name of a shell function) to handle input from file descriptor fd. Installing a handler for an fd which is already handled causes the existing handler to be replaced. Any number of handlers for any number of readable file descriptors may be installed. Note that zle makes no attempt to check whether this fd is actually readable when installing the handler. The user must make their own arrangements for handling the file descriptor when zle is not active.

When zle is attempting to read data, it will examine both the terminal and the list of handled fd’s. If data becomes available on a handled fd, zle calls handler with the fd which is ready for reading as the first argument. Under normal circumstances this is the only argument, but if an error was detected, a second argument provides details: `*hup*’ for a disconnect, `*nval*’ for a closed or otherwise invalid descriptor, or `*err*’ for any other condition. Systems that support only the `select’ system call always use `*err*’.

If the option -w is also given, the handler is instead a line editor widget, typically a shell function made into a widget using `*zle -N*’. In that case handler can use all the facilities of zle to update the current editing line. Note, however, that as handling fd takes place at a low level changes to the display will not automatically appear; the widget should call `*zle -R*’ to force redisplay. As of this writing, widget handlers only support a single argument and thus are never passed a string for error state, so widgets must be prepared to test the descriptor themselves.

If either type of handler produces output to the terminal, it should call `*zle -I*’ before doing so (see below). Handlers should not attempt to read from the terminal.

If no handler is given, but an fd is present, any handler for that fd is removed. If there is none, an error message is printed and status 1 is returned.

If no arguments are given, or the -L option is supplied, a list of handlers is printed in a form which can be stored for later execution.

An fd (but not a handler) may optionally be given with the -L option; in this case, the function will list the handler if any, else silently return status 1.

Note that this feature should be used with care. Activity on one of the fd’s which is not properly handled can cause the terminal to become unusable. Removing an fd handler from within a signal trap may cause unpredictable behavior.

Here is a simple example of using this feature. A connection to a remote TCP port is created using the ztcp command; see the description of the zsh/net/tcp module in /zshmodules/(1). Then a handler is installed which simply prints out any data which arrives on this connection. Note that `select’ will indicate that the file descriptor needs handling if the remote side has closed the connection; we handle that by testing for a failed read.

        if ztcp pwspc 2811; then
          tcpfd=$REPLY
          handler() {
            zle -I
            local line
            if ! read -r line <&$1; then
              # select marks this fd if we reach EOF,
              # so handle this specially.
              print "[Read on fd $1 failed, removing.]" >&2
              zle -F $1
              return 1
            fi
            print -r - $line
          }
          zle -F $tcpfd handler
        fi

-I

Unusually, this option is most useful outside ordinary widget functions, though it may be used within if normal output to the terminal is required. It invalidates the current zle display in preparation for output; typically this will be from a trap function. It has no effect if zle is not active. When a trap exits, the shell checks to see if the display needs restoring, hence the following will print output in such a way as not to disturb the line being edited:

        TRAPUSR1() {
          # Invalidate zle display
          [[ -o zle ]] && zle -I
          # Show output
          print Hello
        }

In general, the trap function may need to test whether zle is active before using this method (as shown in the example), since the zsh/zle module may not even be loaded; if it is not, the command can be skipped.

It is possible to call `*zle -I*’ several times before control is returned to the editor; the display will only be invalidated the first time to minimise disruption.

Note that there are normally better ways of manipulating the display from within zle widgets; see, for example, `*zle -R*’ above.

The returned status is zero if zle was invalidated, even though this may have been by a previous call to `*zle -I*’ or by a system notification. To test if a zle widget may be called at this point, execute zle with no arguments and examine the return status.

-T

This is used to add, list or remove internal transformations on the processing performed by the line editor. It is typically used only for debugging or testing and is therefore of little interest to the general user.

`*zle -T* transformation func’ specifies that the given transformation (see below) is effected by shell function func.

`*zle -Tr* transformation’ removes the given transformation if it was present (it is not an error if none was).

`*zle -TL*’ can be used to list all transformations currently in operation.

Currently the only transformation is tc. This is used instead of outputting termcap codes to the terminal. When the transformation is in operation the shell function is passed the termcap code that would be output as its first argument; if the operation required a numeric argument, that is passed as a second argument. The function should set the shell variable REPLY to the transformed termcap code. Typically this is used to produce some simply formatted version of the code and optional argument for debugging or testing. Note that this transformation is not applied to other non-printing characters such as carriage returns and newlines.

(no term)

widget [ -n num ] [ -Nw ] [ -K keymap ] args … :: Invoke the specified widget. This can only be done when ZLE is active; normally this will be within a user-defined widget.

With the options -n and -N, the current numeric argument will be saved and then restored after the call to widget; `*-n* num’ sets the numeric argument temporarily to num, while `*-N*’ sets it to the default, i.e. as if there were none.

With the option -K, keymap will be used as the current keymap during the execution of the widget. The previous keymap will be restored when the widget exits.

Normally, calling a widget in this way does not set the special parameter WIDGET and related parameters, so that the environment appears as if the top-level widget called by the user were still active. With the option -w, WIDGET and related parameters are set to reflect the widget being executed by the zle call.

Any further arguments will be passed to the widget; note that as standard argument handling is performed, any general argument list should be preceded by --. If it is a shell function, these are passed down as positional parameters; for builtin widgets it is up to the widget in question what it does with them. Currently arguments are only handled by the incremental-search commands, the history-search-forward and -backward and the corresponding functions prefixed by vi-, and by universal-argument. No error is flagged if the command does not use the arguments, or only uses some of them.

The return status reflects the success or failure of the operation carried out by the widget, or if it is a user-defined widget the return status of the shell function.

A non-zero return status causes the shell to beep when the widget exits, unless the BEEP options was unset or the widget was called via the zle command. Thus if a user defined widget requires an immediate beep, it should call the beep widget directly.

#+end_quote

All actions in the editor are performed by `widgets’. A widget’s job is simply to perform some small action. The ZLE commands that key sequences in keymaps are bound to are in fact widgets. Widgets can be user-defined or built in.

The standard widgets built into ZLE are listed in Standard Widgets below. Other built-in widgets can be defined by other modules (see /zshmodules/(1)). Each built-in widget has two names: its normal canonical name, and the same name preceded by a `*.*’. The `*.*’ name is special: it can’t be rebound to a different widget. This makes the widget available even when its usual name has been redefined.

User-defined widgets are defined using `*zle -N*’, and implemented as shell functions. When the widget is executed, the corresponding shell function is executed, and can perform editing (or other) actions. It is recommended that user-defined widgets should not have names starting with `*.*’.

User-defined widgets, being implemented as shell functions, can execute any normal shell command. They can also run other widgets (whether built-in or user-defined) using the zle builtin command. The standard input of the function is redirected from /dev/null to prevent external commands from unintentionally blocking ZLE by reading from the terminal, but read -k or read -q can be used to read characters. Finally, they can examine and edit the ZLE buffer being edited by reading and setting the special parameters described below.

These special parameters are always available in widget functions, but are not in any way special outside ZLE. If they have some normal value outside ZLE, that value is temporarily inaccessible, but will return when the widget function exits. These special parameters in fact have local scope, like parameters created in a function using local.

Inside completion widgets and traps called while ZLE is active, these parameters are available read-only.

Note that the parameters appear as local to any ZLE widget in which they appear. Hence if it is desired to override them this needs to be done within a nested function:

    widget-function() {
      # $WIDGET here refers to the special variable
      # that is local inside widget-function
      () {
         # This anonymous nested function allows WIDGET
         # to be used as a local variable.  The -h
         # removes the special status of the variable.
         local -h WIDGET
      }
    }

BUFFER (scalar) The entire contents of the edit buffer. If it is written to, the cursor remains at the same offset, unless that would put it outside the buffer.

BUFFERLINES (integer)

The number of screen lines needed for the edit buffer currently displayed on screen (i.e. without any changes to the preceding parameters done after the last redisplay); read-only.

CONTEXT (scalar)

The context in which zle was called to read a line; read-only. One of the values:

start The start of a command line (at prompt PS1).

cont

A continuation to a command line (at prompt PS2).

select

In a select loop (at prompt PS3).

vared

Editing a variable in vared.

CURSOR (integer)

The offset of the cursor, within the edit buffer. This is in the range 0 to $#BUFFER, and is by definition equal to $#LBUFFER. Attempts to move the cursor outside the buffer will result in the cursor being moved to the appropriate end of the buffer.

CUTBUFFER (scalar)

The last item cut using one of the `*kill-’ commands; the string which the next yank would insert in the line. Later entries in the kill ring are in the array *killring. Note that the command `*zle copy-region-as-kill* string’ can be used to set the text of the cut buffer from a shell function and cycle the kill ring in the same way as interactively killing text.

HISTNO (integer)

The current history number. Setting this has the same effect as moving up or down in the history to the corresponding history line. An attempt to set it is ignored if the line is not stored in the history. Note this is not the same as the parameter HISTCMD, which always gives the number of the history line being added to the main shell’s history. HISTNO refers to the line being retrieved within zle.

ISEARCHMATCH_ACTIVE (integer)

ISEARCHMATCH_START (integer)

ISEARCHMATCH_END (integer) ISEARCHMATCH_ACTIVE indicates whether a part of the BUFFER is currently matched by an incremental search pattern. ISEARCHMATCH_START and ISEARCHMATCH_END give the location of the matched part and are in the same units as CURSOR. They are only valid for reading when ISEARCHMATCH_ACTIVE is non-zero.

All parameters are read-only.

KEYMAP (scalar)

The name of the currently selected keymap; read-only.

KEYS (scalar)

The keys typed to invoke this widget, as a literal string; read-only.

KEYS_QUEUED_COUNT (integer)

The number of bytes pushed back to the input queue and therefore available for reading immediately before any I/O is done; read-only. See also PENDING; the two values are distinct.

killring (array)

The array of previously killed items, with the most recently killed first. This gives the items that would be retrieved by a yank-pop in the same order. Note, however, that the most recently killed item is in $CUTBUFFER; $killring shows the array of previous entries.

The default size for the kill ring is eight, however the length may be changed by normal array operations. Any empty string in the kill ring is ignored by the yank-pop command, hence the size of the array effectively sets the maximum length of the kill ring, while the number of non-zero strings gives the current length, both as seen by the user at the command line.

LASTABORTEDSEARCH (scalar)

The last search string used by an interactive search that was aborted by the user (status 3 returned by the search widget).

LASTSEARCH (scalar)

The last search string used by an interactive search; read-only. This is set even if the search failed (status 0, 1 or 2 returned by the search widget), but not if it was aborted by the user.

LASTWIDGET (scalar)

The name of the last widget that was executed; read-only.

LBUFFER (scalar)

The part of the buffer that lies to the left of the cursor position. If it is assigned to, only that part of the buffer is replaced, and the cursor remains between the new $LBUFFER and the old $RBUFFER.

MARK (integer)

Like CURSOR, but for the mark. With vi-mode operators that wait for a movement command to select a region of text, setting MARK allows the selection to extend in both directions from the initial cursor position.

NUMERIC (integer)

The numeric argument. If no numeric argument was given, this parameter is unset. When this is set inside a widget function, builtin widgets called with the zle builtin command will use the value assigned. If it is unset inside a widget function, builtin widgets called behave as if no numeric argument was given.

PENDING (integer)

The number of bytes pending for input, i.e. the number of bytes which have already been typed and can immediately be read. On systems where the shell is not able to get this information, this parameter will always have a value of zero. Read-only. See also KEYS_QUEUED_COUNT; the two values are distinct.

PREBUFFER (scalar)

In a multi-line input at the secondary prompt, this read-only parameter contains the contents of the lines before the one the cursor is currently in.

PREDISPLAY (scalar)

Text to be displayed before the start of the editable text buffer. This does not have to be a complete line; to display a complete line, a newline must be appended explicitly. The text is reset on each new invocation (but not recursive invocation) of zle.

POSTDISPLAY (scalar)

Text to be displayed after the end of the editable text buffer. This does not have to be a complete line; to display a complete line, a newline must be prepended explicitly. The text is reset on each new invocation (but not recursive invocation) of zle.

RBUFFER (scalar)

The part of the buffer that lies to the right of the cursor position. If it is assigned to, only that part of the buffer is replaced, and the cursor remains between the old $LBUFFER and the new $RBUFFER.

REGION_ACTIVE (integer)

Indicates if the region is currently active. It can be assigned 0 or 1 to deactivate and activate the region respectively. A value of 2 activates the region in line-wise mode with the highlighted text extending for whole lines only; see Character Highlighting below.

region_highlight (array)

Each element of this array may be set to a string that describes highlighting for an arbitrary region of the command line that will take effect the next time the command line is redisplayed. Highlighting of the non-editable parts of the command line in PREDISPLAY and POSTDISPLAY are possible, but note that the P flag is needed for character indexing to include PREDISPLAY.

Each string consists of the following parts:

· Optionally, a `*P*’ to signify that the start and end offset that follow include any string set by the PREDISPLAY special parameter; this is needed if the predisplay string itself is to be highlighted. Whitespace may follow the `*P*’.

·

A start offset in the same units as CURSOR, terminated by whitespace.

·

An end offset in the same units as CURSOR, terminated by whitespace.

·

A highlight specification in the same format as used for contexts in the parameter zle_highlight, see the section `Character Highlighting’ below; for example, standout or fg=red,bold

For example,

      region_highlight=("P0 20 bold")

specifies that the first twenty characters of the text including any predisplay string should be highlighted in bold.

Note that the effect of region_highlight is not saved and disappears as soon as the line is accepted.

The final highlighting on the command line depends on both region_highlight and zle_highlight; see the section CHARACTER HIGHLIGHTING below for details.

registers (associative array)

The contents of each of the vi register buffers. These are typically set using vi-set-buffer followed by a delete, change or yank command.

SUFFIX_ACTIVE (integer)

SUFFIX_START (integer)

SUFFIX_END (integer) SUFFIX_ACTIVE indicates whether an auto-removable completion suffix is currently active. SUFFIX_START and SUFFIX_END give the location of the suffix and are in the same units as CURSOR. They are only valid for reading when SUFFIX_ACTIVE is non-zero.

All parameters are read-only.

UNDO_CHANGE_NO (integer)

A number representing the state of the undo history. The only use of this is passing as an argument to the undo widget in order to undo back to the recorded point. Read-only.

UNDO_LIMIT_NO (integer)

A number corresponding to an existing change in the undo history; compare UNDO_CHANGE_NO. If this is set to a value greater than zero, the undo command will not allow the line to be undone beyond the given change number. It is still possible to use `*zle undo* change’ in a widget to undo beyond that point; in that case, it will not be possible to undo at all until UNDO_LIMIT_NO is reduced. Set to 0 to disable the limit.

A typical use of this variable in a widget function is as follows (note the additional function scope is required):

      () {
        local UNDO_LIMIT_NO=$UNDO_CHANGE_NO
        # Perform some form of recursive edit.
      }

WIDGET (scalar)

The name of the widget currently being executed; read-only.

WIDGETFUNC (scalar)

The name of the shell function that implements a widget defined with either zle -N or zle -C. In the former case, this is the second argument to the zle -N command that defined the widget, or the first argument if there was no second argument. In the latter case this is the third argument to the zle -C command that defined the widget. Read-only.

WIDGETSTYLE (scalar)

Describes the implementation behind the completion widget currently being executed; the second argument that followed zle -C when the widget was defined. This is the name of a builtin completion widget. For widgets defined with zle -N this is set to the empty string. Read-only.

YANK_ACTIVE (integer)

YANK_START (integer)

YANK_END (integer) YANK_ACTIVE indicates whether text has just been yanked (pasted) into the buffer. YANK_START and YANK_END give the location of the pasted text and are in the same units as CURSOR. They are only valid for reading when YANK_ACTIVE is non-zero. They can also be assigned by widgets that insert text in a yank-like fashion, for example wrappers of bracketed-paste. See also zle -f.

YANK_ACTIVE is read-only.

ZLE_RECURSIVE (integer)

Usually zero, but incremented inside any instance of recursive-edit. Hence indicates the current recursion level.

ZLE_RECURSIVE is read-only.

ZLE_STATE (scalar)

Contains a set of space-separated words that describe the current zle state.

Currently, the states shown are the insert mode as set by the overwrite-mode or vi-replace widgets and whether history commands will visit imported entries as controlled by the set-local-history widget. The string contains `*insert*’ if characters to be inserted on the command line move existing characters to the right or `*overwrite*’ if characters to be inserted overwrite existing characters. It contains `*localhistory*’ if only local history commands will be visited or `*globalhistory*’ if imported history commands will also be visited.

The substrings are sorted in alphabetical order so that if you want to test for two specific substrings in a future-proof way, you can do match by doing:

      if [[ $ZLE_STATE == *globalhistory*insert* ]]; then ...; fi

The following is a list of all the standard widgets, and their default bindings in emacs mode, vi command mode and vi insert mode (the `*emacs*’, `*vicmd*’ and `*viins*’ keymaps, respectively).

Note that cursor keys are bound to movement keys in all three keymaps; the shell assumes that the cursor keys send the key sequences reported by the terminal-handling library (termcap or terminfo). The key sequences shown in the list are those based on the VT100, common on many modern terminals, but in fact these are not necessarily bound. In the case of the viins keymap, the initial escape character of the sequences serves also to return to the vicmd keymap: whether this happens is determined by the KEYTIMEOUT parameter, see /zshparam/(1).

The line editor has the ability to highlight characters or regions of the line that have a particular significance. This is controlled by the array parameter zle_highlight, if it has been set by the user.

If the parameter contains the single entry none all highlighting is turned off. Note the parameter is still expected to be an array.

Otherwise each entry of the array should consist of a word indicating a context for highlighting, then a colon, then a comma-separated list of the types of highlighting to apply in that context.

The contexts available for highlighting are the following:

default Any text within the command line not affected by any other highlighting. Text outside the editable area of the command line is not affected.

isearch

When one of the incremental history search widgets is active, the area of the command line matched by the search string or pattern.

region

The currently selected text. In emacs terminology, this is referred to as the region and is bounded by the cursor (point) and the mark. The region is only highlighted if it is active, which is the case after the mark is modified with set-mark-command or exchange-point-and-mark. Note that whether or not the region is active has no effect on its use within emacs style widgets, it simply determines whether it is highlighted. In vi mode, the region corresponds to selected text in visual mode.

special

Individual characters that have no direct printable representation but are shown in a special manner by the line editor. These characters are described below.

suffix

This context is used in completion for characters that are marked as suffixes that will be removed if the completion ends at that point, the most obvious example being a slash (/) after a directory name. Note that suffix removal is configurable; the circumstances under which the suffix will be removed may differ for different completions.

paste

Following a command to paste text, the characters that were inserted.

When region_highlight is set, the contexts that describe a region – isearch, region, suffix, and paste – are applied first, then region_highlight is applied, then the remaining zle_highlight contexts are applied. If a particular character is affected by multiple specifications, the last specification wins.

zle_highlight may contain additional fields for controlling how terminal sequences to change colours are output. Each of the following is followed by a colon and a string in the same form as for key bindings. This will not be necessary for the vast majority of terminals as the defaults shown in parentheses are widely used.

fg_start_code (\e[3) The start of the escape sequence for the foreground colour. This is followed by one to three ASCII digits representing the colour. Only used for palette colors, i.e. not 24-bit colors specified via a color triplet.

fg_default_code (9)

The number to use instead of the colour to reset the default foreground colour.

fg_end_code (m)

The end of the escape sequence for the foreground colour.

bg_start_code (\e[4)

The start of the escape sequence for the background colour. See fg_start_code above.

bg_default_code (9)

The number to use instead of the colour to reset the default background colour.

bg_end_code (m)

The end of the escape sequence for the background colour.

The available types of highlighting are the following. Note that not all types of highlighting are available on all terminals:

none No highlighting is applied to the given context. It is not useful for this to appear with other types of highlighting; it is used to override a default.

*fg=*/colour/

The foreground colour should be set to colour, a decimal integer, the name of one of the eight most widely-supported colours or as a `*#*’ followed by an RGB triplet in hexadecimal format.

Not all terminals support this and, of those that do, not all provide facilities to test the support, hence the user should decide based on the terminal type. Most terminals support the colours black, red, green, yellow, blue, magenta, cyan and white, which can be set by name. In addition. default may be used to set the terminal’s default foreground colour. Abbreviations are allowed; b or bl selects black. Some terminals may generate additional colours if the bold attribute is also present.

On recent terminals and on systems with an up-to-date terminal database the number of colours supported may be tested by the command `*echotc* Co’; if this succeeds, it indicates a limit on the number of colours which will be enforced by the line editor. The number of colours is in any case limited to 256 (i.e. the range 0 to 255).

Some modern terminal emulators have support for 24-bit true colour (16 million colours). In this case, the hex triplet format can be used. This consists of a `*#*’ followed by either a three or six digit hexadecimal number describing the red, green and blue components of the colour. Hex triplets can also be used with 88 and 256 colour terminals via the zsh/nearcolor module (see /zshmodules/(1)).

Colour is also known as color.

*bg=*/colour/

The background colour should be set to colour. This works similarly to the foreground colour, except the background is not usually affected by the bold attribute.

bold

The characters in the given context are shown in a bold font. Not all terminals distinguish bold fonts.

standout

The characters in the given context are shown in the terminal’s standout mode. The actual effect is specific to the terminal; on many terminals it is inverse video. On some such terminals, where the cursor does not blink it appears with standout mode negated, making it less than clear where the cursor actually is. On such terminals one of the other effects may be preferable for highlighting the region and matched search string.

underline

The characters in the given context are shown underlined. Some terminals show the foreground in a different colour instead; in this case whitespace will not be highlighted.

The characters described above as `special’ are as follows. The formatting described here is used irrespective of whether the characters are highlighted:

ASCII control characters Control characters in the ASCII range are shown as `*^*’ followed by the base character.

Unprintable multibyte characters

This item applies to control characters not in the ASCII range, plus other characters as follows. If the MULTIBYTE option is in effect, multibyte characters not in the ASCII character set that are reported as having zero width are treated as combining characters when the option COMBINING_CHARS is on. If the option is off, or if a character appears where a combining character is not valid, the character is treated as unprintable.

Unprintable multibyte characters are shown as a hexadecimal number between angle brackets. The number is the code point of the character in the wide character set; this may or may not be Unicode, depending on the operating system.

Invalid multibyte characters

If the MULTIBYTE option is in effect, any sequence of one or more bytes that does not form a valid character in the current character set is treated as a series of bytes each shown as a special character. This case can be distinguished from other unprintable characters as the bytes are represented as two hexadecimal digits between angle brackets, as distinct from the four or eight digits that are used for unprintable characters that are nonetheless valid in the current character set.

Not all systems support this: for it to work, the system’s representation of wide characters must be code values from the Universal Character Set, as defined by IS0 10646 (also known as Unicode).

Wrapped double-width characters

When a double-width character appears in the final column of a line, it is instead shown on the next line. The empty space left in the original position is highlighted as a special character.

If zle_highlight is not set or no value applies to a particular context, the defaults applied are equivalent to

    zle_highlight=(region:standout special:standout
    suffix:bold isearch:underline paste:standout)

i.e. both the region and special characters are shown in standout mode.

Within widgets, arbitrary regions may be highlighted by setting the special array parameter region_highlight; see above.